// Diki 0.07 ( http://www.kmonos.net/alang/dee/diki/ ) //
//                     presnted by k.inaba under NYSL. //

import std.string;
import std.conv   : toInt;
import std.regexp : RegExp, sub;

//=========================================================================
// Main
//=========================================================================

void main()
{
	auto w = new WikiPage(
		env("PATH_INFO"),                                         // ページ名
		new Data("diki_db"),                                      // データ保存するディレクトリ
		new View("http://"~env("SERVER_NAME")~env("SCRIPT_NAME")) // CGIスクリプトのURI
	);

	if( env("REQUEST_METHOD") == "POST" )
	{
		auto e = readStdIn(env("CONTENT_LENGTH").toInt())[2..$].uri_decode();
		if( e.length > 0 ) w.write(e);   // POSTデータがあればwrite
		else               w.remove();   // POSTデータがなければremove
	}
	else if( env("QUERY_STRING") == "" ) w.read(); // QUERYが空ならread
	else                                 w.edit(); // なんかあればedit
}

//=========================================================================
// General Utilities
//=========================================================================

/// 環境変数

import std.c.stdlib;
string env( string var )
{
	char* e = getenv( var.toStringz() );
	return e ? toString(e) : "";
}

/// URI エンコード/デコード

import std.uri;
string uri_encode( string s )
{
	return s.encode().replace("+","%2B").replace(" ","+" );
}
string uri_decode( string s )
{
	return s.replace("+"," ").replace("%2B","+").decodeComponent();
}

/// HTMLエスケープ

string text( string s )
{
	return s.replace("&","&amp;").replace("<","&lt;").replace(">","&gt;").replace("\"","&quot;");
}

/// 標準入出力

import std.cstream;
void p( string s )
{
	dout.writeLine(s);
}
string readStdIn( uint size )
{
	ubyte[] buf = new ubyte[size];

	int x=0, y=1;
	for( ; x<size && y!=0; x+=y )
		y = din.readBlock( buf.ptr+x, size-x );

	buf.length = x;
	return cast(string) buf;
}

//=========================================================================
// ここから Wiki 関係のいろいろ
//=========================================================================

class WikiPage
{
private:
	this( string p, Data d, View r ) { page=p; db=d; vw=r; }
	Data   db;
	View   vw;
	string page;

public:
	void read()
	{
		vw.render( page, db );
	}

	void edit()
	{
		vw.render( page, db, true );
	}

	void write( string data )
	{
		db[page] = data;
		vw.redirect_to( page );
	}

	void remove()
	{
		db.remove( page );
		vw.redirect_to( "/" );
	}
}

//=========================================================================
// Database
//=========================================================================

import std.file;
import std.path;

class Data
{
	private string dbDir;
	private string filename_of( string key )
		{ return dbDir ~ uri_encode(as_pagename(key)).replace("/","%2F"); }
	string as_pagename( string s )
		{ return (s.length==0 || s[0]!='/') ? '/'~s : s; }

	this( string dir )
	{
		dbDir = (dir[dir.length-1]=='/' ? dir : dir~"/");
		try { mkdir(dbDir); } catch( Exception e ) {}
	}
	string opIndex( string key )
	{
		try {
			return cast(string) .read( filename_of(key) );
		} catch( FileException e ) { try {
			return cast(string) .read( filename_of("template") );
		} catch( FileException e ) {} }
		return "";
	}
	void opIndexAssign( string data, string key )
	{
		.write( filename_of(key), cast(void[]) data );
	}
	void remove( string key )
	{
		.remove( filename_of(key) );
	}
	int opApply( int delegate(inout string) dg )
	{
		string[] pages;
		listdir( dbDir, (DirEntry* de){
			if( !de.isdir ) pages ~= de.name.getBaseName().uri_decode();
			return true; });

		int r;
		foreach( inout p; pages.sort )
			if( int r = dg(p) )
				return r;
		return 0;
	}
}

//=========================================================================
// Rendering Engine
//=========================================================================

class View
{
private:
	this( string s ) { self_path = s; }
	string self_path;

public:
	void render( string page, Data db, bool edit = false )
	{
		p( `Content-type: text/html; charset=utf-8` );
		p( `` );
		p( `<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.1//EN"` );
		p( `  "http://www.w3.org/TR/xhtml11/DTD/xhtml11.dtd">` );
		p( `<html xmlns="http://www.w3.org/1999/xhtml">` );
		p( `<head>` );
		p( `  <title>` ~(edit ? "Editing :: " : "") ~ text(page) ~ `</title>` );
		p( `  <link rel="stylesheet" href="`~  self_path.getDirName() ~`/diki.css" type="text/css" />` );
	  if(edit)
		p( `  <meta name="robots" content="noindex,nofollow" />` );
		p( `</head><body>` );
	  if(edit) {
		p( `<form action="` ~ page_uri(page) ~ `" method="POST">` );
		p( `<input type="submit" value="post" />` );
		p( `<textarea cols="80" rows="20" name="e" wrap("virtual">` );
		p( text( db[page] )~`</textarea></form>` );
	  } else
		render_lines( page, db[page].splitlines(), db );
		p( `</body></html>` );
	}

	void redirect_to( string page )
	{
		p( `Status: `   ~ `303 See Other` );
		p( `Location: ` ~ page_uri(page)  );
		p( `` );
	}

private:
	string page_uri(string p)
	{
		return self_path ~ uri_encode(p);
	}

	void render_lines( string page, string[] lines, Data db )
	{
		// 閉じてないpreタグがあったら閉じるようにラップした一行出力
		bool in_pre = false;
		void p( string s )
		  { if( in_pre ) {.p(`</pre>`); in_pre=false;} .p(s); }
		scope(exit) p(``);

		// aタグ生成 (url と name はエスケープ済み文字列を渡すこと)
		string a( string url, string name )
			{ return `<a href="` ~url~ `">` ~name~ `</a>`; }

		// メインループ
		foreach( str; lines )
		{
			bool hr()
			{
				if( 0 != str.find("----") )
					return false;
				p( `<hr/>` );
				return true;
			}
			bool heading()
			{
				int N = RegExp("[^\\*]").find(str);
				if( N<1 || 6<N )
					return false;
				p( `<h`~.toString(N)~`>`~text(str[N..$])~`</h`~.toString(N)~`>` );
				return true;
			}
			bool ls()
			{
				if( str.length<3 || str[0..3]!="#ls" )
					return false;
				RegExp r = new RegExp(str[3..$].strip());

				p( `<ul>` );
				foreach( x; db )
					if( r.match(x) )
						p( `  <li>`~a(page_uri(x),x)~`</li>` );
				p( `</ul>` );
				return true;
			}
			bool pre()
			{
				if( !in_pre && str!="" ) { p("<pre>"); in_pre=true; }

				string gen( RegExp r )
				{
					string nam = r.match(1);
					string url = r.match(3) ? r.match(3) : nam;

					if( url.find("http://")==0 || url.find("https://")==0 || url.find("ftp://")==0 )
						return a(url, nam);
					else if( url=="EDIT" )
						return a(page_uri(db.as_pagename(page))~`?e`, nam);
					else if( url=="TURL" )
						return a("http://tinyurl.com/create.php?url="~page_uri(db.as_pagename(page)), nam);
					else
						return a(page_uri(db.as_pagename(url)), nam);
				}
				.p( text(str).sub(`\[\[([^\|]+)(\|(.+))?\]\]`, &gen, `g`) );
					// ToDo : [[]]の中身がescapeされるのがちょっとなあ...
				return true;
			}

			heading() || hr() || ls() || pre();
		}
	}
}